#!/usr/bin/perl -w
 
 # Perl script that implements the Lambda Lounge Vending Machine Specification
 # Tom Wheeler: Mon Apr  6 22:12:27 CDT 2009
 
 use strict;
 
 my $money_in = 0;
 
 # current stock of items for sale
 my %item_count = (
    'a' => 10, 'b' => 10, 'c' => 10,
 );
 
 my %item_value = (
    'a' => 65, 'b' => 100, 'c' => 150,
 );
 
 # current stock of various coins
 my %coin_count = (
    'nickel' => 10, 'dime' => 10, 'quarter' => 10, 'dollar' => 10,
 );
 
 my %coin_value = (
    'nickel'  => 5, 'dime' => 10, 'quarter' => 25, 'dollar' => 100,
 );
 
 prompt();
 while (chomp(my $input = <>)) {
     if    ($input =~ /^EXIT$/i)        { exit; }
     elsif ($input =~ /^NICKEL$/i)      { insert('nickel'); }
     elsif ($input =~ /^DIME$/i)        { insert('dime'); }
     elsif ($input =~ /^QUARTER$/i)     { insert('quarter'); }
     elsif ($input =~ /^DOLLAR$/i)      { insert('dollar'); }
     elsif ($input =~ /^GET-A$/i)       { sell('a'); }
     elsif ($input =~ /^GET-B$/i)       { sell('b'); }
     elsif ($input =~ /^GET-C$/i)       { sell('c'); }
     elsif ($input =~ /^COIN RETURN$/i) { coin_return(); }
     elsif ($input =~ /^SERVICE$/i)     { service(); }
     else  {
        print "\tIgnoring unrecognized command '$input'\n";
     }
 
     prompt();
 }
 
 sub prompt {
    print "> ";
 }
 
 sub insert {
    my $coin = shift;
    my $value = $coin_value{$coin};
 
    $money_in += $value;
    $coin_count{$coin} = $coin_count{$coin} + 1;
 
    my $count = $coin_count{$coin};
    print "\t$coin (value: $value cents) accepted; credit: $money_in cents\n";
 }
 
 sub sell {
    my $item = shift;
 
    my $count = $item_count{$item};
    if ($count <= 0) {
        print "\tSorry, we're out of stock on item '$item'\n";
        return;
    }
 
    my $value = $item_value{$item};
    if ($value > $money_in) {
        my $shortage = $value - $money_in;
        print "\tSorry, that costs $value. Insert $shortage cents, please.\n";
        return;
    }
 
    $item_count{$item} = $item_count{$item} - 1;
    $money_in = $money_in - $value;
 
    print "\tSold item '" . uc($item) . "' for $value cents; returning change\n";
    coin_return();
 }
 
 sub coin_return {
    # sort coins by descending order of value
    my @sorted_coins = sort { 
       $coin_value{$b} <=> $coin_value{$a};
    } keys %coin_count;
   
    foreach my $coin(@sorted_coins) {
       my $coin_value = $coin_value{$coin};
       next if $money_in < $coin_value;
 
       my $num_coins = int($money_in / $coin_value);
       my $count = $coin_count{$coin};
       $num_coins = $count if $num_coins > $count;
 
       $coin_count{$coin} = $count - $num_coins;
       $money_in = $money_in - $num_coins * $coin_value;
 
       print "\tReturned $num_coins " . uc($coin) . "s\n";
    }
 
    if ($money_in) {
        print "\tInsufficient change: You have a credit of $money_in cents\n";
    }
 }
 
 sub service {
    print "\tEntering machine service mode\n";
 
    print "\tCoins\n";
    add_coins_or_items(\%coin_count);
 
    print "\tItems\n";
    add_coins_or_items(\%item_count);
 
    print "\tExiting machine service mode\n";
 }
 
 sub add_coins_or_items {
    my $hash_ref = shift; 
    my %hash = %$hash_ref;
 
    print "\n";
    foreach my $thing(keys %hash) {
        my $count = $hash{$thing};
        print "\tHow many " . uc($thing) . "s to add (there are now $count)?\n";
        prompt();
        my $line = <STDIN>;
 
        last if $line =~ /END/i;
        unless ($line && $line =~ /^[0-9]+$/) {
            print "Ignoring invalid input\n";
            next;
        }
 
        my $num_to_add = int($line);
        next unless $num_to_add > 0;
 
        $hash{$thing} = $count + $num_to_add;
     }
 
     show_counts(\%hash);
 }
 
 sub show_counts {
    my $hash_ref = shift; 
    my %hash = %$hash_ref;
 
    foreach my $thing(keys %hash) {
        my $count = $hash{$thing};
        print "\tThere are currently $count of '" . uc($thing) . "'\n";
    }
 }